!Keyword: portfolio, Markowitz;
! PBUD and PRET are the dual prices or LaGrange multipliers
! on the BUDGET and RETURN constraints;
! The MIN row simply gives the order of the variables;
 MIN ATT + GMC + USX + PBUD + PRET
  Subject to
! The first order conditions, essentially,
!     2 ' Cov ' X + PBUD - Return ' PRET >= 0;
FATT) .02161508 ATT + .02481442 GMC + .02615026 USX 
       + PBUD - 1.089083 PRET >= 0
FGMC) .02481442 ATT + .11678340 GMC + .11085278 USX
       + PBUD - 1.213667 PRET >= 0
FUSX) .02615026 ATT + .11085278 GMC + .18845362 USX
       + PBUD - 1.234583 PRET >= 0
!
! The Budget constraint;
BUD) ATT + GMC + USX = 1
! The target Return constraint;
RET) 1.089083 ATT + 1.213667 GMC + 1.234583 USX >= 1.15
END
! Tell LINDO that this is a quadratic problem with 
!  first real constraint being row 5;
QCP 5