!Keyword: portfolio, Markowitz, transaction costs;
MIN   ATT + GMC + USX + BA + SA + BG + SG + BU + SU 
      + PBUD + PRET + PTA + PTG + PTU
  SUBJECT TO
! First order conditions on the amount invested in each asset;
    FATT) 0.021615 ATT + 0.0248144 GMC + 0.0261502 USX
          + PBUD - 1.089083 PRET + PTA >= 0
    FGMC) 0.0248144 ATT + 0.1167834 GMC + 0.1108528 USX
          + PBUD - 1.213667 PRET + PTG >= 0
    FUSX) 0.0261502 ATT + 0.1108528 GMC + 0.1884536 USX 
          + PBUD - 1.234583 PRET + PTU >= 0
! First order condition on amount bought of ATT;
     FBA)   0.01 PBUD - PTA >=  0
! First order condition on amount sold of ATT;
     FSA)   0.01 PBUD + PTA >=  0
! First order condtion on amount bought of GMC, etc.
     FBG)   0.01 PBUD - PTG >=  0
     FSG)   0.01 PBUD + PTG >=  0
     FBU)   0.01 PBUD - PTU >=  0
     FSU)   0.01 PBUD + PTU >=  0
! Budget constraint at beginning of period;
     BUD) ATT + GMC + USX + 0.01 BA + 0.01 SA
       + 0.01 BG + 0.01 SG + 0.01 BU + 0.01 SU = 1
! Constraint on required expected return at end;
     RET) 1.089083 ATT + 1.213667 GMC + 1.234583 USX >= 1.15
! Invested in ATT - bought + sold = initial holding;
      TA)   ATT - BA + SA =  0.5
!  Ditto for GMC, and USX;
      TG)   GMC - BG + SG =  0.35
      TU)   USX - BU + SU =  0.15
  END
  QCP=   11


